Submission #1220286
Source Code Expand
/+ dub.sdl:
name "A"
dependency "dcomp" version=">=0.6.0"
+/
import std.stdio, std.algorithm, std.range, std.conv;
import std.typecons;
// import dcomp.foundation, dcomp.scanner;
// import dcomp.modint;
alias Mint = ModInt!(10^^9+7);
Mint solve(T)(T g, int[2][] rng) {
int n = g.length.to!int;
Mint[][] dp = new Mint[][](n, 2*n+10);
bool[][] used = new bool[][](n, 2*n+10);
Mint calc(int p, int b, int x) {
if (x < rng[p][0] || rng[p][1] < x) return Mint(0);
if (used[p][x]) return dp[p][x];
used[p][x] = true;
Mint ans = 1;
foreach (e; g[p]) {
int d = e.to;
if (d == b) continue;
ans *= (calc(d, p, x-1)+calc(d, p, x+1));
}
return dp[p][x] = ans;
}
Mint sm = 0;
foreach (i; rng[0][0]..rng[0][1]+1) {
sm += calc(0, -1, i);
}
return sm;
}
int main() {
auto sc = new Scanner(stdin);
alias Edge = Tuple!(int, "to");
int n;
sc.read(n);
Edge[][] g = new Edge[][](n);
foreach (i; 0..n-1) {
int a, b;
sc.read(a, b); a--; b--;
g[a] ~= Edge(b);
g[b] ~= Edge(a);
}
auto pa = g.diameter;
int m = pa.length.to!int;
int[2][] rng = new int[2][](n);
void dfs(int p, int b, int down, int up) {
rng[p] = [down, up];
foreach (e; g[p]) {
int d = e.to;
if (d == b) continue;
dfs(d, p, down+1, up-1);
}
}
if (m % 2 == 0) {
int a = pa[m/2-1], b = pa[m/2];
dfs(a, b, 0, m-2);
dfs(b, a, 1, m-1);
Mint ans1 = solve(g, rng);
dfs(a, b, 0, m);
dfs(b, a, 1, m-1);
Mint ans2 = solve(g, rng);
dfs(a, b, 1, m-1);
dfs(b, a, 0, m);
Mint ans3 = solve(g, rng);
// writeln(ans1, " ", ans2, " ", ans3);
writeln(ans2+ans3-ans1-ans1);
} else {
int a = pa[m/2];
dfs(a, -1, 0, m-1);
writeln(solve(g, rng));
}
return 0;
}
int[] diameter(T)(T g) {
int n = g.length.to!int;
int[] rt = new int[n];
int[2] lng;
void dfs(int p, int b, int dps = 0) {
rt[p] = b;
if (lng[1] < dps) {
lng = [p, dps];
}
foreach (e; g[p]) {
int d = e.to;
if (d == b) continue;
dfs(d, p, dps+1);
}
}
lng = [-1, -1];
dfs(0, -1);
int v = lng[0];
lng = [-1, -1];
dfs(v, -1);
int[] path;
int u = lng[0];
while (u != v) {
path ~= u;
u = rt[u];
}
path ~= v;
return path;
}
/* IMPORT /home/yosupo/Program/dcomp/source/dcomp/modint.d */
// module dcomp.modint;
// import dcomp.numeric.primitive;
struct ModInt(uint MD) if (MD < int.max) {
import std.conv : to;
uint v;
this(int v) {this(long(v));}
this(long v) {this.v = (v%MD+MD)%MD;}
static auto normS(uint x) {return (x<MD)?x:x-MD;}
static auto make(uint x) {ModInt m; m.v = x; return m;}
auto opBinary(string op:"+")(ModInt r) const {return make(normS(v+r.v));}
auto opBinary(string op:"-")(ModInt r) const {return make(normS(v+MD-r.v));}
auto opBinary(string op:"*")(ModInt r) const {return make( (long(v)*r.v%MD).to!uint );}
auto opBinary(string op:"/")(ModInt r) const {return this*inv(r);}
auto opOpAssign(string op)(ModInt r) {return mixin ("this=this"~op~"r");}
static ModInt inv(ModInt x) {return ModInt(extGcd!int(x.v, MD)[0]);}
string toString() {return v.to!string;}
}
unittest {
static assert( is(ModInt!(uint(1000000000) * 2))); //not overflow
static assert(!is(ModInt!(uint(1145141919) * 2))); //overflow!
alias Mint = ModInt!(10^^9+7);
// negative check
assert(Mint(-1).v == 10^^9 + 6);
assert(Mint(-1L).v == 10^^9 + 6);
Mint a = 48;
Mint b = Mint.inv(a);
assert(b.v == 520833337);
Mint c = Mint(15);
Mint d = Mint(3);
assert((c/d).v == 5);
}
struct DModInt(string name) {
import std.conv : to;
static uint MD;
uint v;
this(int v) {this(long(v));}
this(long v) {this.v = ((v%MD+MD)%MD).to!uint;}
auto normS(uint x) {return (x<MD)?x:x-MD;}
auto make(uint x) {DModInt m; m.MD = MD; m.v = x; return m;}
auto opBinary(string op:"+")(DModInt r) {
return make(normS(v+r.v));
}
auto opBinary(string op:"-")(DModInt r) {
return make(normS(v+MD-r.v));
}
auto opBinary(string op:"*")(DModInt r) {
return make((long(v)*r.v%MD).to!uint);
}
auto opBinary(string op:"/")(DModInt r) {
return this*inv(r);
}
auto opOpAssign(string op)(DModInt r) {return mixin ("this=this"~op~"r");}
static DModInt inv(DModInt x) {
return DModInt(extGcd!int(x.v, MD)[0]);
}
string toString() {return v.to!string;}
}
unittest {
alias Mint = DModInt!("default");
Mint.MD = 10^^9 + 7;
//negative check
assert(Mint(-1).v == 10^^9 + 6);
assert(Mint(-1L).v == 10^^9 + 6);
Mint a = Mint(48);
Mint b = Mint.inv(a);
assert(b.v == 520833337);
Mint c = Mint(15);
Mint d = Mint(3);
assert((c/d).v == 5);
}
template isModInt(T) {
const isModInt =
is(T : ModInt!MD, uint MD) || is(S : DModInt!S, string s);
}
T[] factTable(T)(size_t length) if (isModInt!T) {
import std.range : take, recurrence;
import std.array : array;
return T(1).recurrence!((a, n) => a[n-1]*T(n)).take(length).array;
}
// optimize
T[] invFactTable(T)(size_t length) if (isModInt!T) {
import std.algorithm : map, reduce;
import std.range : take, recurrence, iota;
import std.array : array;
auto res = new T[length];
res[$-1] = T(1) / iota(1, length).map!T.reduce!"a*b";
foreach_reverse (i, v; res[0..$-1]) {
res[i] = res[i+1] * T(i+1);
}
return res;
}
T[] invTable(T)(size_t length) if (isModInt!T) {
auto f = factTable!T(length);
auto invf = invFactTable!T(length);
auto res = new T[length];
foreach (i; 1..length) {
res[i] = invf[i] * f[i-1];
}
return res;
}
unittest {
import std.stdio;
alias Mint = ModInt!(10^^9 + 7);
auto r = factTable!Mint(20);
Mint a = 1;
assert(r[0] == Mint(1));
foreach (i; 1..20) {
a *= Mint(i);
assert(r[i] == a);
}
auto p = invFactTable!Mint(20);
foreach (i; 1..20) {
assert((r[i]*p[i]).v == 1);
}
}
/* IMPORT /home/yosupo/Program/dcomp/source/dcomp/foundation.d */
// module dcomp.foundation;
//fold(for old compiler)
static if (__VERSION__ <= 2070) {
template fold(fun...) if (fun.length >= 1) {
auto fold(R, S...)(R r, S seed) {
import std.algorithm : reduce;
static if (S.length < 2) {
return reduce!fun(seed, r);
} else {
import std.typecons : tuple;
return reduce!fun(tuple(seed), r);
}
}
}
unittest {
import std.stdio;
auto l = [1, 2, 3, 4, 5];
assert(l.fold!"a+b"(10) == 25);
}
}
version (X86) static if (__VERSION__ < 2071) {
int bsf(ulong v) {
foreach (i; 0..64) {
if (v & (1UL << i)) return i;
}
return -1;
}
int bsr(ulong v) {
foreach_reverse (i; 0..64) {
if (v & (1UL << i)) return i;
}
return -1;
}
int popcnt(ulong v) {
int c = 0;
foreach (i; 0..64) {
if (v & (1UL << i)) c++;
}
return c;
}
}
/* IMPORT /home/yosupo/Program/dcomp/source/dcomp/scanner.d */
// module dcomp.scanner;
class Scanner {
import std.stdio : File;
import std.conv : to;
import std.range : front, popFront, array, ElementType;
import std.array : split;
import std.traits : isSomeChar, isStaticArray, isArray;
import std.algorithm : map;
File f;
this(File f) {
this.f = f;
}
char[512] lineBuf;
char[] line;
private bool succ() {
import std.range.primitives : empty, front, popFront;
import std.ascii : isWhite;
while (true) {
while (!line.empty && line.front.isWhite) {
line.popFront;
}
if (!line.empty) break;
if (f.eof) return false;
line = lineBuf[];
f.readln(line);
}
return true;
}
private bool readSingle(T)(ref T x) {
import std.algorithm : findSplitBefore;
import std.string : strip;
import std.conv : parse;
if (!succ()) return false;
static if (isArray!T) {
alias E = ElementType!T;
static if (isSomeChar!E) {
//string or char[10] etc
//todo optimize
auto r = line.findSplitBefore(" ");
x = r[0].strip.dup;
line = r[1];
} else {
auto buf = line.split.map!(to!E).array;
static if (isStaticArray!T) {
//static
assert(buf.length == T.length);
}
x = buf;
line.length = 0;
}
} else {
x = line.parse!T;
}
return true;
}
int read(T, Args...)(ref T x, auto ref Args args) {
if (!readSingle(x)) return 0;
static if (args.length == 0) {
return 1;
} else {
return 1 + read(args);
}
}
}
unittest {
import std.path : buildPath;
import std.file : tempDir;
import std.algorithm : equal;
import std.stdio : File;
string fileName = buildPath(tempDir, "kyuridenanmaida.txt");
auto fout = File(fileName, "w");
fout.writeln("1 2 3");
fout.writeln("ab cde");
fout.writeln("1.0 1.0 2.0");
fout.close;
Scanner sc = new Scanner(File(fileName, "r"));
int a;
int[2] b;
char[2] c;
string d;
double e;
double[] f;
sc.read(a, b, c, d, e, f);
assert(a == 1);
assert(equal(b[], [2, 3]));
assert(equal(c[], "ab"));
assert(equal(d, "cde"));
assert(e == 1.0);
assert(equal(f, [1.0, 2.0]));
}
unittest {
import std.path : buildPath;
import std.file : tempDir;
import std.algorithm : equal;
import std.stdio : File, writeln;
import std.datetime;
string fileName = buildPath(tempDir, "kyuridenanmaida.txt");
auto fout = File(fileName, "w");
foreach (i; 0..1_000_000) {
fout.writeln(3*i, " ", 3*i+1, " ", 3*i+2);
}
fout.close;
writeln("Scanner Speed Test(3*1,000,000 int)");
StopWatch sw;
sw.start;
Scanner sc = new Scanner(File(fileName, "r"));
foreach (i; 0..500_000) {
int a, b, c;
sc.read(a, b, c);
assert(a == 3*i);
assert(b == 3*i+1);
assert(c == 3*i+2);
}
foreach (i; 500_000..700_000) {
int[3] d;
sc.read(d);
int a = d[0], b = d[1], c = d[2];
assert(a == 3*i);
assert(b == 3*i+1);
assert(c == 3*i+2);
}
foreach (i; 700_000..1_000_000) {
int[] d;
sc.read(d);
assert(d.length == 3);
int a = d[0], b = d[1], c = d[2];
assert(a == 3*i);
assert(b == 3*i+1);
assert(c == 3*i+2);
}
writeln(sw.peek.msecs, "ms");
}
/* IMPORT /home/yosupo/Program/dcomp/source/dcomp/numeric/primitive.d */
// module dcomp.numeric.primitive;
import std.traits;
T pow(T, U)(T x, U n) if (!isFloatingPoint!T && isIntegral!U) {
return pow(x, n, T(1));
}
T pow(T, U)(T x, U n, T e) if (isIntegral!U) {
while (n) {
if (n & 1) e *= x;
x *= x;
n /= 2;
}
return e;
}
unittest {
assert(pow(3, 5) == 243);
assert(pow(3, 5, 2) == 486);
}
T lcm(T)(in T a, in T b) {
import std.numeric : gcd;
return a / gcd(a,b) * b;
}
unittest {
assert(lcm(2, 4) == 4);
assert(lcm(3, 5) == 15);
assert(lcm(1, 1) == 1);
assert(lcm(0, 100) == 0);
}
//a*T[0]+b*T[1]=T[2], T[2]=gcd
//todo: to binary extgcd
T[3] extGcd(T)(in T a, in T b)
if (!isIntegral!T || isSigned!T) //unsignedはNG
{
if (b==0) {
return [1, 0, a];
} else {
auto e = extGcd(b, a%b);
return [e[1], e[0]-a/b*e[1], e[2]];
}
}
unittest {
import std.numeric : gcd;
foreach (i; 0..100) {
foreach (j; 0..100) {
auto e = extGcd(i, j);
assert(e[2] == gcd(i, j));
assert(e[0] * i + e[1] * j == e[2]);
}
}
}
Submission Info
Submission Time |
|
Task |
D - Oriented Tree |
User |
yosupo |
Language |
D (LDC 0.17.0) |
Score |
1800 |
Code Size |
12930 Byte |
Status |
AC |
Exec Time |
78 ms |
Memory |
31868 KB |
Judge Result
Set Name |
Sample |
All |
Score / Max Score |
0 / 0 |
1800 / 1800 |
Status |
|
|
Set Name |
Test Cases |
Sample |
0_00.txt, 0_01.txt, 0_02.txt, 0_03.txt |
All |
0_00.txt, 0_01.txt, 0_02.txt, 0_03.txt, 1_00.txt, 1_01.txt, 1_02.txt, 1_03.txt, 1_04.txt, 1_05.txt, 1_06.txt, 1_07.txt, 1_08.txt, 1_09.txt, 1_10.txt, 1_11.txt, 1_12.txt, 1_13.txt, 1_14.txt, 1_15.txt, 1_16.txt, 1_17.txt, 1_18.txt, 1_19.txt, 1_20.txt, 1_21.txt, 1_22.txt, 1_23.txt, 1_24.txt, 1_25.txt, 1_26.txt, 1_27.txt, 1_28.txt |
Case Name |
Status |
Exec Time |
Memory |
0_00.txt |
AC |
1 ms |
256 KB |
0_01.txt |
AC |
1 ms |
256 KB |
0_02.txt |
AC |
1 ms |
256 KB |
0_03.txt |
AC |
1 ms |
256 KB |
1_00.txt |
AC |
1 ms |
256 KB |
1_01.txt |
AC |
27 ms |
13308 KB |
1_02.txt |
AC |
78 ms |
30972 KB |
1_03.txt |
AC |
6 ms |
12540 KB |
1_04.txt |
AC |
12 ms |
31740 KB |
1_05.txt |
AC |
6 ms |
12668 KB |
1_06.txt |
AC |
13 ms |
31100 KB |
1_07.txt |
AC |
7 ms |
12412 KB |
1_08.txt |
AC |
14 ms |
30972 KB |
1_09.txt |
AC |
16 ms |
31868 KB |
1_10.txt |
AC |
8 ms |
12796 KB |
1_11.txt |
AC |
20 ms |
31868 KB |
1_12.txt |
AC |
10 ms |
13052 KB |
1_13.txt |
AC |
35 ms |
30716 KB |
1_14.txt |
AC |
18 ms |
12156 KB |
1_15.txt |
AC |
22 ms |
13436 KB |
1_16.txt |
AC |
26 ms |
12796 KB |
1_17.txt |
AC |
6 ms |
11900 KB |
1_18.txt |
AC |
6 ms |
13692 KB |
1_19.txt |
AC |
6 ms |
12156 KB |
1_20.txt |
AC |
12 ms |
31612 KB |
1_21.txt |
AC |
6 ms |
12412 KB |
1_22.txt |
AC |
6 ms |
12412 KB |
1_23.txt |
AC |
5 ms |
12028 KB |
1_24.txt |
AC |
6 ms |
13052 KB |
1_25.txt |
AC |
6 ms |
13564 KB |
1_26.txt |
AC |
6 ms |
10492 KB |
1_27.txt |
AC |
6 ms |
13308 KB |
1_28.txt |
AC |
5 ms |
11900 KB |